u=18mm;
 textscale=u/12mm;

 % this MetaPost script generates a PostScript file, which is then included in a
 % TeX document. if you want to generate EPS from this, you'll have to uncomment
 % the following line. (and probably do a couple more things, to boot.)
 %prologues := 1;

 def cone =
   begingroup;
   save pmax,dmax,persp,persp_nt,tens,arr;
   save harr,rarr;
   save p,d;
   save axisprotrusion;
   save xax,yax,zax;
   save height,width,heightu,widthu;
   pmax = 2; dmax = 0;
   persp_nt = 0.5;
   tens = 2-persp_nt;
   persp = persp_nt*u;
   arr = 0.3u; % how far to offset the arrows from the diagram
   axisprotrusion = 0.4u;  % how far do the axes protrude?
   pair harr[],rarr[]; % endpoints for arrows
   path p[],d[]; % just plain paths for now
   pair xax[],yax[],zax[]; % x,y,z are taken; these are for the axes
   % parameters for the actual cone
   height = 1;
   width = 1.5;
   heightu = height*u;
   widthu = width*u;
   % solid paths
   p0 = (0,0)--(widthu/2,heightu);
   p1 = (0,0)--(-widthu/2,heightu);
   p2 = fullcircle scaled u xscaled width yscaled persp_nt shifted (0,heightu);
   % dotted paths
   % don't draw this; it's reference for the y-axis
   d99 = halfcircle scaled u xscaled 2 yscaled (2*persp_nt) rotated 180;
   % endpoints of dimension arrows
   harr0 = (widthu/2,0);
   harr1 = (widthu/2,heightu);
   rarr0 = (0,heightu);
   rarr1 = (widthu/2,heightu);

   % actually draw
   pickup pencircle scaled 1pt;
   for i=0 upto pmax:
     draw p[i];
   endfor;
   drawdblarrow (harr0..harr1);
   label.rt(btex $h$ etex scaled textscale,.5[harr0,harr1]);
   drawdblarrow (rarr0..rarr1);
   label.top(btex $r$ etex scaled textscale,.3[rarr0,rarr1]);
   % x axis
   xax0 = (0,0);
   xax1 = (widthu/2+arr,0);
   drawarrow (xax0..xax1);
   label.rt(btex $x$ etex scaled textscale,xax1);
   % y axis
   yax0 = (0,0);
   yax1 = point 1 of d99;
   yax2 = (width*persp_nt)[yax0,yax1];
   drawarrow (yax0..yax2);
   label.bot(btex $y$ etex scaled textscale,yax2);
   % z axis
   zax0 = (0,0);
   zax1 = (0,heightu);
   zax2 = (0,heightu+axisprotrusion);
   drawarrow (zax1..zax2);
   draw zax0..zax1 dashed evenly;
   label.top(btex $z$ etex scaled textscale,zax2);
   endgroup;
 enddef;

 beginfig(1)
   cone;
 endfig;